초음파 센서(HC-SR04)

초음파를 사용하여 거리를 측정하는 센서 입니다.

환경에 따라 사용 가능 범위에 오차가 발생합니다.

[초음파 발생 -> 초음파 반사 -> 되돌아온 초음파 감지] 순서로 거리 값을 측정합니다.

센서 작동 방식

1. trig로 초음파를 발생시킨다.

2. 초음파 발생 종료 직후 echo에 HIGH 상태를 유지시킨다.

3. 발생시킨 초음파가 되돌아와서 감지될 경우 echo를 LOW로 변경한다.

4. pulseIn(echoPin, HIGH); 을 사용하여 초음파가 갔다가 돌아오는 시간을 얻어낸다.

5. 이후 식에 대입하여 거리를 측정한다.

거리 측정

초음파 속도	340m/s
초음파 왕복 시간	x
물체와의 거리	y

$y={\frac {17}{10^{3}}}x[cm]$​

​

​

사양

• 작동 전압 : 5V
• 작동 전류 : 15mA
• 작동 주파수 : 40Hz
• 초음파 주파수 : 40kHz
• 최대 감지 거리 : 4m
• 최소 감지 거리 : 2cm
• 측정 각도 범위 : 15 degree
• Trigger Input : 10µs TTL pulse

필요 하드웨어

• 초음파 센서(HC-SR04)
• 아두이노 보드
• 점퍼 케이블

연결

Trig, Echo는 원하는 핀번호로 설정하여 사용합니다.(본문에서는 D3, D4핀으로 사용)

HC-SR04	Arduino UNO
GND	GND
VCC	5V
Trig	D3(변경 가능)
Echo	D4(변경 가능)

예제 코드

시리얼 모니터로 거리를 확인하는 예제입니다.

#define trigPin 3
#define echoPin 4

//초음파가 되돌아 오기까지의 시간을 담을 변수 생성
double pulseTime;

void setup()
{
    //각 핀별 사용방법 설정
    pinMode(trigPin, OUTPUT);
    pinMode(echoPin, INPUT);
    
    //9600 설정
    Serial.begin(9600);
    delay(2000);
    Serial.println("연결 성공");
    delay(500);
    
    //trig신호 초기화
    digitalWrite(trigPin, LOW);
}

void loop()
{
    //초음파 시작
    digitalWrite(trigPin, HIGH);
    
    //센서 사양대로 10µs 동안 초음파 발생
    delayMicroseconds(10);
    digitalWrite(trigPin, LOW);

    //초음파 왕복 시간 측정
    pulseTime = pulseIn(echoPin, HIGH);

    //물체와의 거리 계산
    double distance_cm = pulseTime * 17 / 1000;
    double distance_m = distance_cm / 100;

    //센서 사양을 벗어날 시 error 표기
    if ((distance_cm < 400) && (distance_cm > 2))
    {
        Serial.print("거리(cm) = ");
        Serial.println(distance_cm);
        Serial.print("거리(m) = ");
        Serial.println(distance_m);
        Serial.println("--------------------------------------------------");
    }
    else
    {
        Serial.println("제품 사용 가능범위 초과");
    }
    delay(1000);
}

고등학교 정보교과서(씨마스) 예제

P. 215 스스로 해결하기③ (초음파 센서, 조도 센서, LED)

본 예제는 교과서 내용에 따라 엔트리파이선을 사용합니다.

아두이노 사용 방법 문서에서 엔트리파이선을 활용 방법을 참고하세요.

연결

초음파 센서의 Trig 핀은 아두이노 8번 핀, Echo 핀은 아두이노 9번 핀에 연결했습니다.

예제 코드

초음파 센서 값이 10 이하일 때를 물체가 감지된 것으로 판단해 LED를 켜고, 부저로 소리를 내는 예제 코드입니다.

import Entry
import Arduino

distance = 1

def when_start():
    while True:
        distance = Arduino.ultrasonicRead(8, 9)
        if (distance > 10):
            Arduino.digitalWrite(10, "LOW")
        else:
            Arduino.digitalWrite(10, "HIGH")
            Arduino.tone(6, "G", 3, 0.2)
            Entry.wait_for_sec(0.2)

구매 링크

• 공집사몰