아두이노 프로젝트 3. 시각장애인을 위한 스마트 지팡이: 두 판 사이의 차이

아두위키 : Arduwiki
시각위키텍스트
편집 요약 없음
잔글 (ArduWiki님이 3. 시각장애인을 위한 스마트 지팡이 문서를 넘겨주기를 만들지 않고 아두이노 프로젝트 3. 시각장애인을 위한 스마트 지팡이 문서로 이동했습니다)
 
(차이 없음)

2024년 5월 31일 (금) 17:37 기준 최신판


개요

시각장애인을 위한 스마트 지팡이

시각장애인이 사용하는 지팡이에 편의 및 안전 기능을 추가하여 보다 유용한 지팡이를 제작합니다.


고려사항

  • 초음파 센서를 활용해 장애물이 가까워질수록 더 강하게 진동합니다.
  • 주변이 어두워질 경우 지팡이에 부착된 네오픽셀이 자동으로 점등합니다.
  • 블루투스로 안드로이드 앱과 지팡이를 연결한 후, 지팡이의 버튼을 누르면 앱에 설정된 문자로 "목적지로 출발", "목적지에 도착", "현재 위치"를 문자로 전송합니다.


사용 하드웨어


회로 구성

기능 구현

/* 스마트 지팡이 프로젝트
사용 부품
- Arduino nano
- 조도센서(cds)
- 저항(1k옴)
- 초음파 센서(HC-SR04) 2개
- 진동모터
- NeoPixel 바
- 버튼 3개
- 블루투스 모듈(HC-06)

기능
- 어두울 시 NeoPixel 점등
- 버튼으로 보호자 문자 발송 기능 : 블루투스 모듈로 지팡이 사용자의 스마트폰에 연결
  - 버튼 1 : 출발 문자 발송
  - 버튼 2 : 도착 문자 발송
  - 버튼 3 : 위험 및 현재 위치 문자 발송
- 초음파센서로 물체 감지
  - 초음파 센서 사양(2cm ~ 400cm 거리의 물체 감지)으로 10cm ~ 350cm 의 구간만 구별 가능하게 하였으며 350 초과시 350, 10 미만 시 10으로 측정되도록 지정
  - 알람(진동)단계별 세기 기능
  - 단위 [cm], 단계가 높아질수록 진동의 세기가 강해짐
    1단계 100 ~ 80
    2단계 80 ~ 60
    3단계 60 ~ 40
    4단계 40 ~ 20
    5단계 0 ~ 20
*/


#include <Adafruit_NeoPixel.h>

#include <SoftwareSerial.h>

#define trigPin_1 3   //1번초음파(상단) trig핀번호
#define echoPin_1 4   //1번초음파(상단) echo핀번호
#define trigPin_2 6   //2번초음파(하단) trig핀번호
#define echoPin_2 7   //2번초음파(하단) echo핀번호
#define vibratePin 5  //진동센서 핀번호(PWM)
#define cds A0        //조도센서 핀번호
#define neoPixel 2    //네오픽셀 핀번호
#define hc06Rx 10     //블루투스 rx 핀번호
#define hc06Tx 9      //블루투스 tx 핀번호
#define btn1 8        //버튼 핀번호(출발)
#define btn2 11       //버튼 핀번호(도착)
#define btn3 12       //버튼 핀번호(긴급)
#define NumPixel 23    //네오픽셀 갯수
#define bright 255    //네오픽셀 밝기

SoftwareSerial BTSerial(hc06Tx, hc06Rx);

Adafruit_NeoPixel neo(NumPixel, neoPixel, NEO_GRB + NEO_KHZ800);

int Btn1, Btn2, Btn3;

double distance_now_top = 0;  //현재 장애물과의 거리 변수
double distance_now_bot = 0;  //현재 장애물과의 거리 변수
int vibratePower = 255;       //진동 세기 변수(0~255)
int vibrateTime = 150;        //진동 유지 시간[ms]
double alert_distance = 100;  //알람작동 거리[cm]

int btnFlg1 = 0;
int btnFlg2 = 0;
int btnFlg3 = 0;
int btn1Chk() {
  if (digitalRead(btn1) == 0) {
    btnFlg1 = 1;
    return 0;
  }
  if (btnFlg1 == 1) {
    btnFlg1 = 0;
    return 1;
  }
  return 0;
}

int btn2Chk() {
  if (digitalRead(btn2) == 0) {
    btnFlg2 = 1;
    return 0;
  }
  if (btnFlg2 == 1) {
    btnFlg2 = 0;
    return 1;
  }
  return 0;
}

int btn3Chk() {
  if (digitalRead(btn3) == 0) {
    btnFlg3 = 1;
    return 0;
  }
  if (btnFlg3 == 1) {
    btnFlg3 = 0;
    return 1;
  }
  return 0;
}


void BTsignal() {
  if (btn1Chk() == 1) BTSerial.println('1');
  else if (btn2Chk() == 1) BTSerial.println('2');
  else if (btn3Chk() == 1) BTSerial.println('3');
}

void setup() {
  BTSerial.begin(9600);
  pinMode(btn1, INPUT_PULLUP);
  pinMode(btn2, INPUT_PULLUP);
  pinMode(btn3, INPUT_PULLUP);
  pinMode(cds, INPUT);
  pinMode(vibratePin, OUTPUT);
  digitalWrite(vibratePin, LOW);
  pinMode(trigPin_1, OUTPUT);
  pinMode(echoPin_1, INPUT);
  pinMode(trigPin_2, OUTPUT);
  pinMode(echoPin_2, INPUT);
  digitalWrite(trigPin_1, LOW);
  digitalWrite(trigPin_2, LOW);
  neo.begin();
  neo.setBrightness(bright);
  neo.clear();
  neo.show();
}

void loop() {
  BTsignal();                                         //블루투스 모듈
  cdsNeo(NumPixel);                                   //조도값 낮을 시 neopixel ON
  distance_now_top = distance(trigPin_1, echoPin_1);  //상단 초음파 센서 장애물 거리
  distance_now_bot = distance(trigPin_2, echoPin_2);  //하단 초음파 센서 장애물 거리

  distance_interval(distance_now_top, distance_now_bot);  //상단 초음파 센서
  distance_interval(distance_now_bot, distance_now_top);  //하단 초음파 센서
  delay(vibrateTime);
}

void distance_interval(double dis_cm, int dis_cm_otherside) {
  if (dis_cm < dis_cm_otherside) {
    if (dis_cm < alert_distance / 5) {  //0~20cm
      analogWrite(vibratePin, vibratePower);
    } else if (dis_cm < alert_distance / 5 * 2) {  //20~40cm
      analogWrite(vibratePin, vibratePower / 5 * 4);
    } else if (dis_cm < alert_distance / 5 * 3) {  //40~60cm
      analogWrite(vibratePin, vibratePower / 5 * 3);
    } else if (dis_cm < alert_distance / 5 * 4) {  //60~80cm
      analogWrite(vibratePin, vibratePower / 5 * 2);
    } else if (dis_cm < alert_distance) {  //80~100cm
      analogWrite(vibratePin, vibratePower / 5);
    } else {
      analogWrite(vibratePin, 0);
    }
  }
}

void cdsNeo(int i) {
  int val = analogRead(cds);
  if (val > 950) {
    for (int j = 0; j < i; j++)
      neo.setPixelColor(j, bright, bright, bright);
    neo.show();
  } else {
    for (int j = 0; j < i; j++)
      neo.setPixelColor(j, 0, 0, 0);
    neo.show();
  }
}


double distance(int trig, int echo) {
  digitalWrite(trig, HIGH);
  delayMicroseconds(10);
  digitalWrite(trig, LOW);
  double pulseTime = pulseIn(echo, HIGH);
  double distance_cm = pulseTime * 17.33 / 1000;
  if (distance_cm > 350) {
    return 350;
  } else if (distance_cm < 10) {
    return 10;
  }
  return distance_cm;
}

장애물 감지 시 진동 기능

초음파 센서(HC-SR04)를 상단과 하단에 각각 하나씩 부착하여 장애물 감지 거리 구간에 따라 부착된 소형 진동 모터의 세기를 조절합니다.

소형 진동 모터의 경우 진동 세기가 잘 체감될 수 있도록 지팡이의 손잡이에 부착합니다.


주변 밝기 확인 및 네오픽셀 점등

조도 센서(CDS)를 활용해 주변의 밝기를 확인한 후 주변 사람들이 인지할 수 있도록 지팡이에 부착한 네오픽셀이 점등됩니다.

이를 통해 시야 불명에 의한 충돌 사고를 대비합니다.


안드로이드 앱을 통한 문자 전송

HC-06 블루투스 모듈을 활용해 스마트폰의 앱에 연결합니다.

지팡이에는 3개의 택트 스위치가 부착되어 있으며 각각 "목적지로 출발", "목적지에 도착", "현재 위치" 신호의 역할을 합니다.

앱에서 택트 스위치 신호를 수신했다면 미리 설정된 전화번호로 문자를 송신합니다.


결과

사진


Comment

완성된 지팡이의 모습입니다.

불을 끈 어두운 환경에서는 지팡이에 길에 부착된 네오픽셀이 점등한 모습을 확인할 수 있습니다.

상단, 하단에 초음파 센서가 하나씩 부착되어 장애물을 감지하며 작은 동그란 소형 진동 모터가 손잡이 끝에 부착되어 진동합니다.

택트 스위치는 손잡이에 부착되어 사용자가 쉽게 누르고, 누르면 문자가 발송됩니다.


추신

공집사의 아두이노 프로젝트 결과물은 판매되는 제품이 아니며, 프로젝트 수준에서 간단하게 진행되었습니다.

문의 및 의뢰는 크몽 공집사로 연락주시면 감사하겠습니다.

원본 주소 "https://arduwiki.com/html/index.php?title=아두이노_프로젝트_3._시각장애인을_위한_스마트_지팡이&oldid=1024"