ArduWiki: 새 문서: {{#seo:|title=アルドゥウィキ：アルドゥイーノ RTC モジュール (DS1302) ガイド|title_mode=append|keywords=アルドゥイーノ, 情報科学, メーカー学習, パフォーマンス評価, RTC モジュール (DS1302), アルドゥイーノプロジェクト, キャップストーンプロジェクト, アルドゥイーノサンプルコード|description=アルドゥイーノで RTC モジュール (DS1302) を制御する方法（基本情報、回路...

2025-03-20T11:48:33Z

새 문서: {{#seo:|title=アルドゥウィキ：アルドゥイーノ RTC モジュール (DS1302) ガイド|title_mode=append|keywords=アルドゥイーノ, 情報科学, メーカー学習, パフォーマンス評価, RTC モジュール (DS1302), アルドゥイーノプロジェクト, キャップストーンプロジェクト, アルドゥイーノサンプルコード|description=アルドゥイーノで RTC モジュール (DS1302) を制御する方法（基本情報、回路...

새 문서

{{#seo:|title=アルドゥウィキ：アルドゥイーノ RTC モジュール (DS1302) ガイド|title_mode=append|keywords=アルドゥイーノ, 情報科学, メーカー学習, パフォーマンス評価, RTC モジュール (DS1302), アルドゥイーノプロジェクト, キャップストーンプロジェクト, アルドゥイーノサンプルコード|description=アルドゥイーノで RTC モジュール (DS1302) を制御する方法（基本情報、回路、サンプルコード）を紹介します。情報科学とメーカー授業で活用できます。}}
[[File:Rtc모듈대표이미지.jpg|center|class=coders100]]

ボードに接続されていなくても時間を記憶するモジュールです。

バッテリー（CR2032）を使用します。

== '''仕様''' ==
* 動作電圧：3.3V 〜 5V
* 動作電流：2V 基準 300nA

== '''必要なハードウェア''' ==
* RTC モジュール
* Arduino

== '''接続''' ==
{| class="wikitable"
| colspan="1" rowspan="1" |RTC module
| colspan="1" rowspan="1" |Arduino
|-
| colspan="1" rowspan="1" |VCC
| colspan="1" rowspan="1" |5V
|-
| colspan="1" rowspan="1" |GND
| colspan="1" rowspan="1" |GND
|-
| colspan="1" rowspan="1" |CLK
| colspan="1" rowspan="1" |D5
|-
| colspan="1" rowspan="1" |DAT
| colspan="1" rowspan="1" |D4
|-
| colspan="1" rowspan="1" |RST
| colspan="1" rowspan="1" |D3
|}
[[File:Rtc 회로.png|center|class=coders70]]

== '''ライブラリ''' ==
This document uses the Rtc by Makuna library for Arduino. [[Arduino Libraries]]
[[File:Rtc 라이브러리.png|center|class=coders70]]

== '''サンプルコード''' ==
コンパイル時点で時間を保存するコードで、ボードにアップロード時に若干の差が生じます。
（コードコンパイル後にボードにアップロードされるため、アップロード中に誤差が発生）

[[File:Rtc 예제1.png|center|class=coders50]]
<syntaxhighlight lang="c++" line="1">
#include <ThreeWire.h>
#include <RtcDS1302.h>

//--------------------Modified Section-------------------------------
#define CLK 5 //Specify CLK pin number
#define DAT 4 //Specify DAT pin number
#define RST 3 //Specify RST pin number

ThreeWire myWire(DAT,CLK,RST);
//--------------------------------------------------------------
RtcDS1302<ThreeWire> Rtc(myWire);

void setup ()
{
Serial.begin(57600);

Serial.print("compiled: ");
Serial.print(__DATE__);
Serial.println(__TIME__);

Rtc.Begin();

RtcDateTime compiled = RtcDateTime(__DATE__, __TIME__);
printDateTime(compiled);
Serial.println();

if (!Rtc.IsDateTimeValid())
{
// Common Causes:
// 1) first time you ran and the device wasn't running yet
// 2) the battery on the device is low or even missing

Serial.println("RTC lost confidence in the DateTime!");
Rtc.SetDateTime(compiled);
}

if (Rtc.GetIsWriteProtected())
{
Serial.println("RTC was write protected, enabling writing now");
Rtc.SetIsWriteProtected(false);
}

if (!Rtc.GetIsRunning())
{
Serial.println("RTC was not actively running, starting now");
Rtc.SetIsRunning(true);
}

RtcDateTime now = Rtc.GetDateTime();
if (now < compiled)
{
Serial.println("RTC is older than compile time! (Updating DateTime)");
Rtc.SetDateTime(compiled);
}
else if (now > compiled)
{
Serial.println("RTC is newer than compile time. (this is expected)");
}
else if (now == compiled)
{
Serial.println("RTC is the same as compile time! (not expected but all is fine)");
}
}

void loop ()
{
RtcDateTime now = Rtc.GetDateTime();

printDateTime(now);
Serial.println();

if (!now.IsValid())
{
// Common Causes:
// 1) the battery on the device is low or even missing and the power line was disconnected
Serial.println("RTC lost confidence in the DateTime!");
}

delay(10000); // ten seconds
}

#define countof(a) (sizeof(a) / sizeof(a[0]))

void printDateTime(const RtcDateTime& dt)
{
char datestring[20];

snprintf_P(datestring,
countof(datestring),
PSTR("%02u/%02u/%04u %02u:%02u:%02u"),
dt.Month(),
dt.Day(),
dt.Year(),
dt.Hour(),
dt.Minute(),
dt.Second() );
Serial.print(datestring);
}

</syntaxhighlight>

=== 実行結果 ===
[[File:Rtc 실행결과.png|center|class=coders70]]

RTC Module(DS1302) JP - 편집 역사